/**********************************************************************/
/*    Atkinson, Donev, and Tobias, "Optimum Experimental Designs"     */
/*                                                                    */
/*    NAME: Program 20.4                                              */
/*   TITLE: SAS Task 20.4 - Resolution IV designs as Bayesian         */
/*          D-optimum                                                 */
/*    KEYS:                                                           */
/*    DATA:                                                           */
/*                                                                    */
/*  Author: Randy Tobias                                              */
/* History:                                                           */
/*    Created...............................................27Jun2007 */
/**********************************************************************/

title1 "SAS Task 20.4 - Resolution IV designs as Bayesian D-optimum";


/*
/  The FACTEX procedure makes a convenient way to generate the 2**8
/  candidate points.
/---------------------------------------------------------------------*/
proc factex;
   factors a b c d e f g h;
   output out=Can;
run;

/*
/  Find the 16-run Bayesian D-optimum design with main effects as
/  primary terms and interactions as secondary terms.
/---------------------------------------------------------------------*/
proc optex data=Can coding=orthcan;
   model a|b|c|d|e|f|g|h@1, a|b|c|d|e|f|g|h@2 / prior=0,4;
   generate n=16 method=m_fedorov niter=1000 keep=10;
   output out=Design;
run;

/*
/  The aliasing structure for an arbitrary design can be computed
/  using the GLM procedure.
/---------------------------------------------------------------------*/
data Design; set Design;
   y = rannor(1);
proc glm data=Design;
   model y = a|b|c|d|e|f|g|h@1 a|b|c|d|e|f|g|h@2 / e aliasing;
   ods select GAliasing;
run;

title1;