/**********************************************************************/
/*    Atkinson, Donev, and Tobias, "Optimum Experimental Designs"     */
/*                                                                    */
/*    NAME: Program 17.2                                              */
/*   TITLE: Fig. 17.6 - Optimum design for two consecutive            */
/*          first-order models                                        */
/*    KEYS:                                                           */
/*    DATA:                                                           */
/*                                                                    */
/*  Author: Randy Tobias                                              */
/* History:                                                           */
/*    Created...............................................27Jun2007 */
/**********************************************************************/




title1 "Fig. 17.6 - Optimum design for two consecutive first-order models";

data Can; do Time = 0 to 5 by .01; output; end; run;

%let TrueTheta1 = 1.0;
%let TrueTheta2 = 0.5;

data Can; set Can;
   d1 = (2 + 2*Time)*exp(-    Time) - 2*exp(-0.5*Time);
   d2 = (4 - 2*Time)*exp(-0.5*Time) - 4*exp(-    Time);
run;

title2 "Optimum Design Criteria";
proc optex data=Can coding=none;
   model d1 d2 / noint;
   id Time;
   generate n=2 method=m_fedorov niter=1000 keep=10;
   output out=Design;
run;
title2;

title2 "Design Points";
proc sort  data=Design; by Time;
proc print data=Design;
run;
title2;

title2 "Figure 17.6 - Standardized variances for optimum design";
%let pagesize = %sysfunc(getoption(pagesize));
options ps=40;
data Eval; set Design; y = rannor(1); 
data Eval; set Eval Can;
proc reg data=Eval noprint;
   model y = d1 d2 / noint;
   output out=d h=h;
data d; set d;
   d = 2 * h; /* 2 = NObs in Design */
proc plot data=d;
   where (y = .);
   plot d*Time;
run;
options ps=&pagesize;

title2;
title1;