/**********************************************************************/
/*    Atkinson, Donev, and Tobias, "Optimum Experimental Designs"     */
/*                                                                    */
/*    NAME: Program 17.1                                              */
/*   TITLE: Fig. 17.2 & 17.4 - Examples 17.1 and 17.3: Computing      */
/*          Jacobians for directly specified nonlinear models         */
/*    KEYS:                                                           */
/*    DATA:                                                           */
/*                                                                    */
/*  Author: Randy Tobias                                              */
/* History:                                                           */
/*    Created...............................................27Jun2007 */
/**********************************************************************/

title1 "Computing Jacobians for directly specified nonlinear models";

title2 "Fig. 17.2 - Example 17.1: exponential decay, negative derivative";

data Can; do Time = 0 to 4 by .01; output; end; run;

%let TrueTheta = 1;

data Jac; set Can;
   d = -Time*exp(-&TrueTheta*Time);
run;

%let pagesize = %sysfunc(getoption(pagesize));
options ps=40;
data Jac; set Jac;
   dd = -d;
proc plot data=Jac;
   plot dd*Time;
run;
options ps=&pagesize;

title2;




title2 "Fig. 17.4 - Example 17.3: two consecutive first-order reactions";

data Can; do Time = 0 to 5 by .01; output; end; run;

data Jac; set Can;
   d1 = (2 + 2*Time)*exp(-    Time) - 2*exp(-0.5*Time);
   d2 = (4 - 2*Time)*exp(-0.5*Time) - 4*exp(-    Time);
run;

%let pagesize = %sysfunc(getoption(pagesize));
options ps=40;
data Jac; set Jac;
   dd1 = d1*d1;
   dd2 = d2*d2;
proc plot data=Jac;
   plot d1*Time='1' d2*Time='2' / overlay;
run;
options ps=&pagesize;

title2;

title1;