/**********************************************************************/
/*    Atkinson, Donev, and Tobias, "Optimum Experimental Designs"     */
/*                                                                    */
/*    NAME: Program 16.4                                              */
/*   TITLE: Example 16.3: Quadratic constraints for a mixture         */
/*          experiment                                                */
/*    KEYS:                                                           */
/*    DATA:                                                           */
/*   NOTES: Uses the ADX macros to create simplex lattice designs.    */
/*          Also addresses SAS Task 16.6.                             */
/*                                                                    */
/*  Author: Randy Tobias                                              */
/* History:                                                           */
/*    Created...............................................27Jun2007 */
/**********************************************************************/

title1 "Example 16.3: Quadratic constraints for a mixture experiment";

%adxgen;
%adxmix;

/*
/  Generate a large grid and subset it to apply the quadratic
/  constraints.
/---------------------------------------------------------------------*/
%adxsld(Grid,x1 x2 x3,100);
data Grid; set Grid;
   where   (-4.062*x1*x1 + 2.962*x1 + x2 >= 0.6075)
         & (-1.174*x1*x1 + 1.057*x1 + x2 <= 0.5019);
run;

proc optex data=Grid coding=orthcan;
   model x1|x2|x3@2 / noint;
   generate n=6 method=m_fedorov niter=1000 keep=10;
   output out=Design;
proc sort data=Design;
   by descending x1;
proc print data=Design;
run;

title1;