/**********************************************************************/
/*    Atkinson, Donev, and Tobias, "Optimum Experimental Designs"     */
/*                                                                    */
/*    NAME: Program 14.3                                              */
/*   TITLE: Example 14.3 - Second-order response surface              */
/*          with two qualitative factors                              */
/*    KEYS:                                                           */
/*    DATA:                                                           */
/*   NOTES: See also SAS Task 14.1                                    */
/*                                                                    */
/*  Author: Randy Tobias                                              */
/* History:                                                           */
/*    Created...............................................27Jun2007 */
/**********************************************************************/

title1 "Example 14.3 - Second-order response surface with two qualitative factors";

/*
/  Create 3**3 candidate set and use OPTEX to generate the optimal
/  blocked design.
/---------------------------------------------------------------------*/
title2 "Optimal 18-run 2*3-row/column quadratic design over 3**2 grid";
data Candidates;
  do Row=1 to 2; do Col=1 to 3;
    do x1 = -1 to 1;
      do x2 = -1 to 1;
        output;
        end;
      end;
    end; end;
run;

proc optex data=Candidates coding=orthcan seed=354638001;
  class Row Col;
  model Row Col
        x1 x2 x1*x2 x1*x1 x2*x2;
  generate n=18 method=m_fedorov niter=1000 keep=10 initdesign=random;
  output out=Design;
proc sort data=Design;
   by Col Row x1 x2;
proc print data=Design;
  run;
title2;

title1;