/**********************************************************************/
/*    Atkinson, Donev, and Tobias, "Optimum Experimental Designs"     */
/*                                                                    */
/*    NAME: Program 8.2                                               */
/*   TITLE: Regression analysis of log viscosity for filler B         */
/*    KEYS:                                                           */
/*    DATA: Elastomer blend viscosity                                 */
/*                                                                    */
/*  Author: Randy Tobias                                              */
/* History:                                                           */
/*    Created...............................................27Jun2007 */
/**********************************************************************/

title1 "Regression analysis of log viscosity for filler B";

data Elastomer;
   do Oil = 0 to 30 by 10;
      do Filler = 'A','B','C';
         do Level = 0 to 60 by 12;
            input Viscosity @@;
            output;
            end;
         end;
      end;
datalines;
 26  28  30  32  34  37
 26  38  50  76 108 157
 25  30  35  40  50  60
 18  19  20  21  24  24
 17  26  37  53  83 124
 18  21  24  28  33  41
 12  14  14  16  17  17
 13  20  27  37  57  87
 13  15  17  20  24  29
  .  12  12  13  14  14
  .  15  22  27  41  63
 11  14  15  17  18  25
;

/*
/  Compute the logarithm of viscocity in the variable logV.
/---------------------------------------------------------------------*/
data Elastomer; set Elastomer;
   logV = log(Viscosity);
run;


/*
/  Close the listing output destination, open the HTML destination,
/  and turn on the graphics.
/---------------------------------------------------------------------*/
ods listing close;
ods html;
ods graphics on;

proc reg data=Elastomer;
   where (Filler='B');
   model logV = Level Oil;
run;

ods graphics off;
ods html close;
ods listing;
title1;