/**********************************************************************/
/*    Atkinson, Donev, and Tobias, "Optimum Experimental Designs"     */
/*                                                                    */
/*    NAME: Program 8.1                                               */
/*   TITLE: Regression analysis of carbon monoxide desorption         */
/*    KEYS:                                                           */
/*    DATA: Carbon monoxide desorption                                */
/*                                                                    */
/*  Author: Randy Tobias                                              */
/* History:                                                           */
/*    Created...............................................27Jun2007 */
/**********************************************************************/

title1 "Regression analysis of carbon monoxide desorption";
data CO;
   input KCRatio n @@;
   do i = 1 to n; input Desorbed @@; output; end;
datalines;
0.05 2 0.05 0.10
0.25 2 0.25 0.35
0.50 3 0.75 0.85 0.95
1.25 5 1.42 1.75 1.82 1.95 2.45
2.10 6 3.05 3.19 3.25 3.43 3.50 3.93
2.50 4 3.75 3.93 3.99 4.07
;


/*
/  Close the listing output destination, open the HTML destination,
/  and turn on the graphics.
/---------------------------------------------------------------------*/
ods listing close;
ods html;
ods graphics on;

title2 "Default simple linear model";
proc reg data=CO;
   model Desorbed = KCRatio;
run;

title2 "Linear model with no intercept term";
proc reg data=CO;
   model Desorbed = KCRatio / noint;
run;

ods graphics off;
ods html close;
ods listing;
title2;
title1;